juillet, 2018 | SiZiOUS :: Kodeur en Série

Si vous êtes un développeur Java vous connaissez très certainement Apache Maven, qui est à peu près l’équivalent de Make mais pour le monde Java.

Il y a quelques jours j’ai dû réfléchir à une méthode d’extraction des valeurs de certains nœuds du fichier pom.xml pour automatiser certaines opérations. Par exemple, j’ai voulu extraire les valeurs de groupId, artifactId et version depuis un projet Maven, c’est-à-dire depuis le fichier pom.xml.

J’ai finalement créé une solution en pur batch Windows pour le faire, et j’ai appelé ce petit outil POM Tool.

Et voici son code source :

@echo off
setlocal EnableDelayedExpansion
set POM_TOOL_VERSION=20180914

rem Parameters
set MAVEN_POM_INPUT_TAG=%1
set MAVEN_POM_FILE=pom.xml
if "%2" neq "" set MAVEN_POM_FILE=%2

rem Check input parameters
if "%MAVEN_POM_INPUT_TAG%"=="" goto help
if "%MAVEN_POM_FILE%"=="" goto error_pom_not_found
if not exist %MAVEN_POM_FILE% goto error_pom_not_found

rem Compute start/end positions to extract the value from the XML tag
call:strlen %MAVEN_POM_INPUT_TAG%
set /a TAG_BEGIN=%_strlen% + 2
set /a TAG_END=(%TAG_BEGIN% + 1) * -1

rem Perform the XML tag value extraction
call:extractxml %MAVEN_POM_INPUT_TAG% %TAG_BEGIN% %TAG_END%
if "%_extractxml%"=="" goto error_extraction_failed
echo %_extractxml%
goto:eof

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

rem ---
rem Display help message
rem ---
:help
call:banner
echo Usage: %~n0 ^&lt;xml_tag^&gt; [pom_file]
echo.
echo Example: %~n0 version - will return artifact version
echo          %~n0 groupId - will return artifact groupId
goto:eof

rem ---
rem Error: The requested tag was not found
rem ---
:error_extraction_failed
call:banner
echo Error: The tag "%MAVEN_POM_INPUT_TAG%" wasn't found in the "%MAVEN_POM_FILE%" file.
goto:eof

rem ---
rem Error: The Maven POM file wasn't found
rem ---
:error_pom_not_found
call:banner
echo Error: The "%MAVEN_POM_FILE%" file wasn't found.
goto:eof

rem ---
rem Function: banner
rem Used to display the tool banner
rem ---
:banner
echo POM Tool - Ver. %POM_TOOL_VERSION%
echo.
goto:eof

rem ---
rem Function: extractxml 
rem Used to parse %MAVEN_POM_FILE% for extracting tags value.
rem Usage: call:extractxml %param% where %param% is the tag to search.
rem ---
:extractxml
setlocal
set _extracted_xml_result=
set _token=^&lt;%~1^&gt;
set _begin=%~2
set _end=%~3
for /f "tokens=*" %%a in (%MAVEN_POM_FILE%) do (
	set row=%%a
	if /i "!row:%_token%=!"=="!row!" (echo NOP &gt; nul) else (
		set _extracted_xml_result=!row!
		if /i "!_extracted_xml_result!" neq "" goto extractxml_endloop
	)
)
:extractxml_endloop
set "_final=%_extracted_xml_result%"
if "%_final%" neq "" call set _final=%%_final:~%_begin%,%_end%%%
(endlocal
	if "%~1" neq "" set "_extractxml=%_final%"
)
goto:eof

rem ---
rem Function: strlen
rem Get the length of a string
rem Thanks to: SS64 (https://ss64.com/nt/syntax-strlen.html)
rem ---
:strlen
setlocal
set _str=%~1

rem Remove any quotes
set _str=%_str:"=%

rem Test if empty
if not defined _str echo endlocal &amp; set _strlen=0&amp;goto:eof

set MAX_STRING_LENGTH=256
for /l %%g in (0,1,!MAX_STRING_LENGTH!) do (
	REM extract one character
	set "_char=!_str:~%%g,1!"
	REM if _char is empty we are at the end of the string
	if not defined _char endlocal &amp; set _strlen=%%g&amp; goto:eof
)
goto:eof

100

101

102

103

104

105

106

107

108

109

110

111

112

@echo off

setlocal EnableDelayedExpansion

set POM_TOOL_VERSION=20180914

rem Parameters

set MAVEN_POM_INPUT_TAG=%1

set MAVEN_POM_FILE=pom.xml

if "%2" neq "" set MAVEN_POM_FILE=%2

rem Check input parameters

if "%MAVEN_POM_INPUT_TAG%"=="" goto help

if "%MAVEN_POM_FILE%"=="" goto error_pom_not_found

if not exist %MAVEN_POM_FILE% goto error_pom_not_found

rem Compute start/end positions to extract the value from the XML tag

call:strlen %MAVEN_POM_INPUT_TAG%

set /a TAG_BEGIN=%_strlen% + 2

set /a TAG_END=(%TAG_BEGIN% + 1) * -1

rem Perform the XML tag value extraction

call:extractxml %MAVEN_POM_INPUT_TAG% %TAG_BEGIN% %TAG_END%

if "%_extractxml%"=="" goto error_extraction_failed

echo %_extractxml%

goto:eof

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

rem ---

rem Display help message

rem ---

:help

call:banner

echo Usage: %~n0 ^<xml_tag^> [pom_file]

echo.

echo Example: %~n0 version - will return artifact version

echo %~n0 groupId - will return artifact groupId

goto:eof

rem ---

rem Error: The requested tag was not found

rem ---

:error_extraction_failed

call:banner

echo Error: The tag "%MAVEN_POM_INPUT_TAG%" wasn't found in the "%MAVEN_POM_FILE%" file.

goto:eof

rem ---

rem Error: The Maven POM file wasn't found

rem ---

:error_pom_not_found

call:banner

echo Error: The "%MAVEN_POM_FILE%" file wasn't found.

goto:eof

rem ---

rem Function: banner

rem Used to display the tool banner

rem ---

:banner

echo POM Tool - Ver. %POM_TOOL_VERSION%

echo.

goto:eof

rem ---

rem Function: extractxml

rem Used to parse %MAVEN_POM_FILE% for extracting tags value.

rem Usage: call:extractxml %param% where %param% is the tag to search.

rem ---

:extractxml

setlocal

set _extracted_xml_result=

set _token=^<%~1^>

set _begin=%~2

set _end=%~3

for /f "tokens=*" %%a in (%MAVEN_POM_FILE%) do (

set row=%%a

if /i "!row:%_token%=!"=="!row!" (echo NOP > nul) else (

set _extracted_xml_result=!row!

if /i "!_extracted_xml_result!" neq "" goto extractxml_endloop

)

:extractxml_endloop

set "_final=%_extracted_xml_result%"

if "%_final%" neq "" call set _final=%%_final:~%_begin%,%_end%%%

(endlocal

if "%~1" neq "" set "_extractxml=%_final%"

)

goto:eof

rem ---

rem Function: strlen

rem Get the length of a string

rem Thanks to: SS64 (https://ss64.com/nt/syntax-strlen.html)

rem ---

:strlen

setlocal

set _str=%~1

rem Remove any quotes

set _str=%_str:"=%

rem Test if empty

if not defined _str echo endlocal & set _strlen=0&goto:eof

set MAX_STRING_LENGTH=256

for /l %%g in (0,1,!MAX_STRING_LENGTH!) do (

REM extract one character

set "_char=!_str:~%%g,1!"

REM if _char is empty we are at the end of the string

if not defined _char endlocal & set _strlen=%%g& goto:eof

)

goto:eof

Vous devez simplement copier/coller ce code source dans un nouveau fichier texte et l’appeler pomtool.cmd.

L’utilisation est très simple :

pomtool artifactId c:\temp\my-maven-project\pom.xml

1	pomtool artifactId c:\temp\my-maven-project\pom.xml

Ceci va vous donner la valeur du nœud artifactId du fichier c:\temp\my-maven-project\pom.xml !

Bien entendu vous pouvez appeler POM Tool depuis un autre fichier batch, par exemple :

@echo off
for /f "tokens=*" %%i in ('pomtool description c:\my\project\pom.xml') do set "PROJECT_NAME=%%i"
echo %PROJECT_NAME%
pause

@echo off

for /f "tokens=*" %%i in ('pomtool description c:\my\project\pom.xml') do set "PROJECT_NAME=%%i"

echo %PROJECT_NAME%

pause

Dans ce cas, la variable %PROJECT_NAME% contiendra la sortie du programme POM Tool, dans cet exemple il s’agit de la valeur du nœud description du fichier pom.xml ! 🙂

N’hésitez pas à commenter si vous avez des questions ! 🙂

Si le monde de la Sega Dreamcast vous est familier, vous connaissez très certainement le format d’image disques CDI. Les images CDI sont la plupart du temps des images amorçables pour la Dreamcast : il suffit simplement de graver l’image disque CDI puis de mettre le CD-R ainsi gravé dans la console pour lancer le jeu.

Les images CDI sont générées avec un outil nommé Padus DiscJuggler. La dernière version (le développement est arrêté) est la version 6.00.1400 sortie en 2007. Aujourd’hui, je voulais installer cet outil sur mon ordinateur Microsoft Windows 10 Pro x64 Update 1803, mais malheureusement, impossible de l’installer, j’ai systématiquement ce message qui s’affiche :

You need to reboot your system.

C’est évidemment ce que j’ai fait. J’ai redémarré 3 fois mais rien à faire : ce message s’affiche toujours et le logiciel ne s’installe pas.

Après avoir désassemblé l’exécutable, le problème est tout simple. Il est causé par la présence de valeurs dans le Registre de Windows sous la clef RunOnce. Puisque DiscJuggler est un programme 32-bits, il faut donc vérifier si des entrées sont présentes à ces endroits :

HKEY_CURRENT_USER\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\RunOnce\
HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\RunOnce\

1 2	HKEY_CURRENT_USER\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\RunOnce\ HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\RunOnce\

Donc effectivement dans mon cas j’avais bien des valeurs dans les clefs ci-dessus :

Une valeur est présente dans la clef RunOnce

En théorie, il suffit alors de redémarrer l’ordinateur pour que les clefs RunOnce soient vidées automatiquement de leurs valeurs, en effet, les programmes présents dans ces clefs sont en théorie exécutés une seule fois puis ces valeurs sont supprimées (dans la capture d’écran, la valeur ici se nomme PreRun). Mais dans mon cas, rien n’y fait, la clef RunOnce contient toujours quelque chose : ce fameux programme PreRun de Gigabyte ! Cela car je possède effectivement une carte mère Gigabyte et j’ai par conséquent installé certains outils fournis avec ma carte mère. Même en la supprimant à la main (ne pas oublier de lancer regedit en mode Administrateur pour le faire), elle revient toujours automatiquement (il suffit de faire F5 pour la voir réapparaitre au bout de quelques secondes…). Donc l’installation de DiscJuggler affiche toujours You need to reboot your system. …

Dans mon cas, il suffit simplement d’arrêter le service GIGABYTE Adjust pour que la valeur PreRun ne soit pas recréée le temps d’installer DiscJuggler.

Arrêt du service GIGABYTE Adjust

Une fois ceci fait, l’installation peut se faire :

Installation de Padus DiscJuggler 6.00.1400 sous Windows 10

Et cerise sur le gâteau, le programme fonctionne très bien sous Windows 10 ! 🙂

Archives mensuelles : juillet 2018

Apache Maven : Comment extraire les valeurs des noeuds XML depuis le fichier pom.xml (en pur batch !)

Installation de DiscJuggler sous Windows 10